cmake_minimum_required(VERSION 3.15)
project(TakeStamp VERSION 0.1.0)
set(CMAKE_CXX_STANDARD 17)
set(JUCE_DIR "$ENV{HOME}/dev/JUCE" CACHE PATH "JUCE 7 checkout")
add_subdirectory(${JUCE_DIR} juce)
if(APPLE)
  set(TS_FORMATS AU VST3)
else()
  set(TS_FORMATS VST3)   # Linux build = compile/logic check only
endif()

foreach(P Sender Receiver)
  if(P STREQUAL "Sender")
    set(CODE Tss1)
    set(NAME "TakeStamp Send")
  else()
    set(CODE Tsr1)
    set(NAME "TakeStamp Receive")
  endif()
  juce_add_plugin(TakeStamp${P}
    COMPANY_NAME "MarcusX" PLUGIN_MANUFACTURER_CODE Mrcx PLUGIN_CODE ${CODE}
    PRODUCT_NAME "${NAME}" FORMATS ${TS_FORMATS}
    IS_SYNTH FALSE NEEDS_MIDI_INPUT FALSE NEEDS_MIDI_OUTPUT FALSE
    AU_MAIN_TYPE kAudioUnitType_Effect
    COPY_PLUGIN_AFTER_BUILD FALSE)
  target_sources(TakeStamp${P} PRIVATE ${P}/Plugin.cpp)
  target_include_directories(TakeStamp${P} PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/../core)
  target_compile_definitions(TakeStamp${P} PUBLIC
    JUCE_WEB_BROWSER=0 JUCE_USE_CURL=1 JUCE_VST3_CAN_REPLACE_VST2=0 JUCE_DISPLAY_SPLASH_SCREEN=0)
  target_link_libraries(TakeStamp${P} PRIVATE juce::juce_audio_utils juce::juce_audio_formats
    PUBLIC juce::juce_recommended_config_flags juce::juce_recommended_warning_flags)
endforeach()
